Hile çok kullandım o 2. İhtimali bu cevabı yazdıktan sonra çok düşündüm ama

---

---

Dokuldunuz jsjs ben yakalanmam bakarsam yakalarim xd

---

---

@Q47. Deneyelim mi
Neyse konu dağıldı isteğe dönelim

---

---

Yazdığım 2 ci mesaj sonrasında önemi kalmıyor eklentinin kötülemek vs gibi anlaşılmasın daha iyi çalışır hale getirmeye çalışıyoruz

---

---

Verilerini STEAM_ID sine kaydedilebilir steam olmayanlar içinde, ip adresine veyatta ip clasına oda olmadı isme kaydedilebilir

---

---

Aslında bu tedbir amaçlı yapılan birşey. Herhangi bir sunucuda sürekli oynayan bir oyuncu olsan dahi senden 4-5 defa belki de daha fazla teamviewer alınabiliyor ki gelen şikayete ya da yetkililerin insiyatifine kalmış birşey bu. Eklentinin amacı ise en azından oyuncunun içindeki şüpheyi yok etmek. Tabii ki dediğiniz gibi yapacak birçok oyuncu var. En azından %70lik bir kısmın bu eklentide 'Teamviewer kontrol edildi' ibaresini aldıktan sonra hileye başvuracağını düşünmüyorum.

---

---

Denermisiniz iki komut var /twadmin,/tw

PHP Kod:

#include <amxmodx>
#include <nvault>

new bmVault;
#define bmTemel "WEBDiyo"

new bmGenelChatTag[64],bmUstMenuTag[32],bmAltMenuTag[32];
new bmSecilen[33];

public plugin_init(){
    register_plugin
    ("Naber",
    "1.0",
    "Berk");
    
    register_clcmd("say /twadmin","beTWAdmin",ADMIN_BAN);
    register_clcmd("say /tw","beTWNormal");
    
    new bmTag = register_cvar("tw_ChatTag","!n[ !tWEBDiyo.Com !n]");
    get_pcvar_string(bmTag,bmGenelChatTag,charsmax(bmGenelChatTag));
    
    new bmTag2 = register_cvar("tw_MenuUstTag","WEBDiyo.Com");
    get_pcvar_string(bmTag2,bmUstMenuTag,charsmax(bmUstMenuTag));
    
    new bmTag3 = register_cvar("tw_MenuAltTag","WD");
    get_pcvar_string(bmTag3,bmAltMenuTag,charsmax(bmAltMenuTag));
    
}
public plugin_cfg(){
    bmVault = nvault_open("bmTWKayit");
    if(bmVault == INVALID_HANDLE)
        log_amx("%s: Acilmayan nVault Dosyasi Bulundu",bmTemel);
}
public plugin_end(){
    nvault_close(bmVault);
}
public beTWAdmin(bmID){
    new bmYetki = get_user_flags(bmID);
    if(bmYetki & ADMIN_BAN){
        new bmMenu = bmMenuOlustur("Oyuncu Secin","beTWAdmin_devam");
        new bmOyuncular[32],bmSayi,bmUID,bmNTS[6],bmIsim[28];
        get_players(bmOyuncular,bmSayi);
        for(new i; i < bmSayi; i++){
            bmUID = bmOyuncular[i];
            num_to_str(bmUID,bmNTS,charsmax(bmNTS));
            get_user_name(bmUID,bmIsim,charsmax(bmIsim));
            bmMenuSecenekEkle(bmMenu,"\y%s",bmNTS,0,bmIsim);
        }
        bmMenuBitir(bmID,bmMenu);
    }
}
public beTWAdmin_devam(bmID,bmMenu,bmMEsya){
    if(bmMEsya == MENU_EXIT){
        menu_destroy(bmMenu);
        return PLUGIN_HANDLED;
    }
    new bmMVeri[6],bmBos;
    menu_item_getinfo(bmMenu,bmMEsya,bmBos,bmMVeri,5,_,_,bmBos);
    new bmKey = str_to_num(bmMVeri);
    bmSecilen[bmID] = bmKey;
    beTWAyarla(bmID);
    menu_destroy(bmMenu);
    return PLUGIN_HANDLED;
}
public beTWAyarla(bmID){
    new bmMenu = bmMenuOlustur("TW Durumu Ayarla","beTWAyarla_devam");
    new bmDuzenleyeIsim[28],bmDuzenlenenIsim[28];
    get_user_name(bmID,bmDuzenleyeIsim,charsmax(bmDuzenleyeIsim));
    get_user_name(bmSecilen[bmID],bmDuzenlenenIsim,charsmax(bmDuzenlenenIsim));
    bmMenuSecenekEkle(bmMenu,"\yTW Ayarlayan Kullanici\w: \d[\y%s\d]","1",0,bmDuzenleyeIsim);
    bmMenuSecenekEkle(bmMenu,"\yTW Ayarlanacak Kullanici\w: \d[\y%s\d]^n","1",0,bmDuzenlenenIsim);
    bmMenuSecenekEkle(bmMenu,"\yTW Kontrol Edildi","2",0,bmDuzenlenenIsim);
    bmMenuSecenekEkle(bmMenu,"\yTW Kontrol Edilmedi^n","3",0,bmDuzenlenenIsim);
    
    new bmAnahtar[48],bmSteamID[26],bmDurum,bmSonGuncelle[28];
    get_user_authid(bmSecilen[bmID],bmSteamID,charsmax(bmSteamID));
    formatex(bmAnahtar,charsmax(bmAnahtar),"%s-TwKontrol",bmSteamID);
    bmDurum = nvault_get(bmVault,bmAnahtar);
    formatex(bmAnahtar,charsmax(bmAnahtar),"%s-SonGuncelleyen",bmSteamID);
    nvault_get(bmVault,bmAnahtar,bmSonGuncelle,charsmax(bmSonGuncelle));
    
    bmMenuSecenekEkle(bmMenu,"\ySuanki Durum\w: \d[\y%s\d]","1",0,bmDurum == 0  ? "Edilmedi":"Edildi");
    bmMenuSecenekEkle(bmMenu,"\ySon Guncelleyen\w: \d[\y%s\d]","1",0,strlen(bmSonGuncelle) == 0 ? "Yok":bmSonGuncelle);
    bmMenuBitir(bmID,bmMenu);
}
public beTWAyarla_devam(bmID,bmMenu,bmMEsya){
    if(bmMEsya == MENU_EXIT){
        menu_destroy(bmMenu);
        return PLUGIN_HANDLED;
    }
    
    new bmMVeri[6],bmBos;
    menu_item_getinfo(bmMenu,bmMEsya,bmBos,bmMVeri,5,_,_,bmBos);
    new bmKey = str_to_num(bmMVeri);
    
    new bmDuzenleyeIsim[28];
    get_user_name(bmID,bmDuzenleyeIsim,charsmax(bmDuzenleyeIsim));
    new bmAnahtar[48],bmSteamID[26];
    get_user_authid(bmSecilen[bmID],bmSteamID,charsmax(bmSteamID));
    
    switch(bmKey){
        case 1 : {
            beTWAyarla(bmID);
        }
        case 2 : {
            formatex(bmAnahtar,charsmax(bmAnahtar),"%s-TwKontrol",bmSteamID);
            nvault_set(bmVault,bmAnahtar,"1");
            formatex(bmAnahtar,charsmax(bmAnahtar),"%s-SonGuncelleyen",bmSteamID);
            nvault_set(bmVault,bmAnahtar,bmDuzenleyeIsim);
            renkli_yazi(bmID,"%s !gOyuncu kontrolu !n[ !tEdildi !n] !golarak degistirildi!n.",bmGenelChatTag);
            beTWAyarla(bmID);
        }
        case 3 : {
            formatex(bmAnahtar,charsmax(bmAnahtar),"%s-TwKontrol",bmSteamID);
            nvault_set(bmVault,bmAnahtar,"0");
            formatex(bmAnahtar,charsmax(bmAnahtar),"%s-SonGuncelleyen",bmSteamID);
            nvault_set(bmVault,bmAnahtar,bmDuzenleyeIsim);
            renkli_yazi(bmID,"%s !gOyuncu kontrolu !n[ !tEdilmedi !n] !golarak degistirildi!n.",bmGenelChatTag);
            beTWAyarla(bmID);
        }
    }
    menu_destroy(bmMenu);
    return PLUGIN_HANDLED;
}
public beTWNormal(bmID){
    new bmMenu = bmMenuOlustur("Oyuncu Secin","beTWNormal_devam");
    new bmOyuncular[32],bmSayi,bmUID,bmNTS[6],bmIsim[28];
    get_players(bmOyuncular,bmSayi);
    for(new i; i < bmSayi; i++){
        bmUID = bmOyuncular[i];
        num_to_str(bmUID,bmNTS,charsmax(bmNTS));
        get_user_name(bmUID,bmIsim,charsmax(bmIsim));
        bmMenuSecenekEkle(bmMenu,"\y%s",bmNTS,0,bmIsim);
    }
    bmMenuBitir(bmID,bmMenu);
}
public beTWNormal_devam(bmID,bmMenu,bmMEsya){
    if(bmMEsya == MENU_EXIT){
        menu_destroy(bmMenu);
        return PLUGIN_HANDLED;
    }
    new bmMVeri[6],bmBos;
    menu_item_getinfo(bmMenu,bmMEsya,bmBos,bmMVeri,5,_,_,bmBos);
    new bmKey = str_to_num(bmMVeri);
    bmSecilen[bmID] = bmKey;
    beTWBak(bmID);
    menu_destroy(bmMenu);
    return PLUGIN_HANDLED;
}
public beTWBak(bmID){
    new bmMenu = bmMenuOlustur("TW Durumu Bak","beTWBak_devam");
    new bmDuzenlenenIsim[28];
    get_user_name(bmSecilen[bmID],bmDuzenlenenIsim,charsmax(bmDuzenlenenIsim));
    bmMenuSecenekEkle(bmMenu,"\yTW Bakilacak Kullanici\w: \d[\y%s\d]^n","1",0,bmDuzenlenenIsim);
    new bmAnahtar[48],bmSteamID[26],bmDurum,bmSonGuncelle[28];
    get_user_authid(bmSecilen[bmID],bmSteamID,charsmax(bmSteamID));
    formatex(bmAnahtar,charsmax(bmAnahtar),"%s-TwKontrol",bmSteamID);
    bmDurum = nvault_get(bmVault,bmAnahtar);
    formatex(bmAnahtar,charsmax(bmAnahtar),"%s-SonGuncelleyen",bmSteamID);
    nvault_get(bmVault,bmAnahtar,bmSonGuncelle,charsmax(bmSonGuncelle));
    
    bmMenuSecenekEkle(bmMenu,"\ySuanki Durum\w: \d[\y%s\d]","1",0,bmDurum == 0 ?  "Edilmedi":"Edildi");
    bmMenuSecenekEkle(bmMenu,"\ySon Guncelleyen\w: \d[\y%s\d]","1",0,strlen(bmSonGuncelle) == 0 ? "Yok":bmSonGuncelle);
    bmMenuBitir(bmID,bmMenu);
}
public beTWBak_devam(bmID,bmMenu,bmMEsya){
    if(bmMEsya == MENU_EXIT){
        menu_destroy(bmMenu);
        return PLUGIN_HANDLED;
    }
    beTWBak(bmID);
    menu_destroy(bmMenu);
    return PLUGIN_HANDLED;
}
stock bmMenuOlustur(const bmBaslik[],const bmDevam[], any:...){
    new bmYeniBaslik[256],bmDuzeltBaslik[256];
    vformat(bmDuzeltBaslik,charsmax(bmDuzeltBaslik),bmBaslik,3);
    formatex(bmYeniBaslik,charsmax(bmYeniBaslik),"\d[\r%s \d~> \yTW\d] \y%s",bmUstMenuTag,bmDuzeltBaslik);
    new bmMenu = menu_create(bmYeniBaslik,bmDevam);
    return bmMenu;
}
stock bmMenuSecenekEkle(bmMenuID,const bmSecenekBaslik[],const bmBilgi[],bmTag = 1, any:...){
    new bmYeniSecenekBaslik[256],bmSecenekDuzelt[256];
    vformat(bmSecenekDuzelt,charsmax(bmSecenekDuzelt),bmSecenekBaslik,5);
    if(bmTag == 1){
        formatex(bmYeniSecenekBaslik,charsmax(bmYeniSecenekBaslik),"\y[%s] \r# \y%s",bmAltMenuTag,bmSecenekDuzelt);
    }
    else{
        formatex(bmYeniSecenekBaslik,charsmax(bmYeniSecenekBaslik),"%s",bmSecenekDuzelt);
    }
    menu_additem(bmMenuID,bmYeniSecenekBaslik,bmBilgi);
}
stock bmMenuBitir(bmID,bmMenuID,bmSecenek = 1,bmCikis = 1,bmSayfa = 0){
    menu_setprop(bmMenuID,MPROP_EXITNAME,"\rCikis");
    menu_setprop(bmMenuID,MPROP_PERPAGE, bmSecenek ? 7:0 ); 
    menu_setprop(bmMenuID,MPROP_EXIT,bmCikis ? MEXIT_ALL:MEXIT_NEVER);
    menu_display(bmID,bmMenuID,bmSayfa);    
}
#if AMXX_VERSION_NUM < 183
stock renkli_yazi(const id, const input[], any:...){
    new count = 1, players[32];
    static msg[191];
    vformat(msg, 190, input, 3);
    
    replace_all(msg, 190, "!n", "^x01"); // Default Renk(Sarı)
    replace_all(msg, 190, "!g", "^x04"); // Yeşil Renk
    replace_all(msg, 190, "!t", "^x03"); // Takım Renk( CT mavi , T kırmızı )
    
    if (id) players[0] = id; else get_players(players, count, "ch");{
        for (new i = 0; i < count; i++)
        {
            if (is_user_connected(players[i]))
            {
                
                message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i]);
                write_byte(players[i]);
                write_string(msg);
                message_end();
            }
            
        }
    }
    
}
#else
stock renkli_yazi(const id, const input[], any:...){
    static msg[191];
    vformat(msg, 190, input, 3);
    
    replace_all(msg, 190, "!n", "^x01"); 
    replace_all(msg, 190, "!g", "^x04"); 
    replace_all(msg, 190, "!t", "^x03"); 
    
    client_print_color(id, id, msg);
}
#endif 


---

---

takır takır çalışıyor

---

---

Teşekkürler hızlı yaptım biraz birşey olursa özelden yazarsınız geliştirmeler içinde

---

---

Konunuz Çözülmüş İsteklere Taşınmıştır.

---

---