herkese merhaba arkadaşlar;
aşağıda verdiğim sma çalışır durumda fakat modelin içinden geçebiliyoruz bunu engelleyebilirmiyiz?

---

---

Nasıl yani içinden geçe biliyorsunuz?

---

---

Semiclip acıkmıs gibi model var ama katı değil

---

---

func_wall

---

---

....

PHP Kod:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <fakemeta_util>
#include <engine>

#define PLUGIN "Model Spawner"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

#define ADMIN_FLAG ADMIN_RCON

new gCurEnt[33];
new gSensitivity[33];
new gLastItem[33];

new const saveFile[] = "addons/amxmodx/configs/modelspawner_saves.ini";
new const modelFile[] = "addons/amxmodx/configs/modelspawner_models.ini";

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /addmodel","AddModel");
    register_clcmd("say /modelekle","AddModel");
    
    if(!file_exists(saveFile)) {
        new f = fopen(saveFile,"wt");
        fclose(f);
    }
    if(!file_exists(modelFile)) {
        new f = fopen(modelFile,"wt");
        fclose(f);
    }
}
public plugin_cfg() {
    new curMap[32]; get_mapname(curMap,charsmax(curMap));
    static szModel[64], szOrigin[32],szAngle[32],szMap[32], szSeq[4],szAnim[2];
    static szAngle1[10],szAngle2[10],szAngle3[10];
    static szOrigin1[10],szOrigin2[10],szOrigin3[10];
    static Float:origin[3], Float:angle[3], seq,anim;
    static szLine[256], txtlen, maxlines, ent;
    maxlines = file_size(saveFile,1);
    for(new line;line<maxlines;line++) {
        read_file(saveFile,line,szLine,charsmax(szLine),txtlen);
        parse(szLine,szModel,charsmax(szModel),szOrigin,charsmax(szOrigin),szAngle,charsmax(szAngle),\
        szSeq,charsmax(szSeq),szAnim,charsmax(szAnim),szMap,charsmax(szMap));
        
        if(!equali(szMap,curMap)) continue;
        parse(szOrigin,szOrigin1,charsmax(szOrigin1),szOrigin2,charsmax(szOrigin2),szOrigin3,charsmax(szOrigin3));
        parse(szAngle,szAngle1,charsmax(szAngle1),szAngle2,charsmax(szAngle2),szAngle3,charsmax(szAngle3));
        origin[0] = str_to_float(szOrigin1);
        origin[1] = str_to_float(szOrigin2);
        origin[2] = str_to_float(szOrigin3);
        angle[0] = str_to_float(szAngle1);
        angle[1] = str_to_float(szAngle2);
        angle[2] = str_to_float(szAngle3);
        seq = str_to_num(szSeq);
        anim = str_to_num(szAnim);
        
        ent = engfunc(EngFunc_CreateNamedEntity,engfunc(EngFunc_AllocString,"info_target"));
        engfunc(EngFunc_SetOrigin,ent,origin);
        engfunc(EngFunc_SetModel,ent,szModel);
        set_pev(ent,pev_angles,angle);
        entity_set_int(ent, EV_INT_solid, SOLID_BBOX );
        if(anim) {
            set_pev(ent,pev_animtime,2.0);
            set_pev(ent,pev_framerate,1.0);
        }
        set_pev(ent,pev_sequence,seq);
    }
    
    
}
public client_connect(id) {
    gSensitivity[id] = 1;
}
public plugin_precache() {
    new szModel[64],txtlen;
    new maxlines = file_size(modelFile,1);
    for(new line;line<maxlines;line++) {
        read_file(modelFile,line,szModel,charsmax(szModel),txtlen);
        precache_model(szModel);
    }
}
public AddModel(id) {
    if(!access(id,ADMIN_FLAG)) {
        client_print(id,print_chat,"[ Model Spawner ] Bu komut icin yetkili degilsiniz.");
        return PLUGIN_HANDLED
    }
    
    new menu = menu_create("\yModel Secin","AddModelHandle");
    
    static szModel[64],txtlen,maxlines;
    static szModelName[32],data[3];
    new LastModel[64];
    maxlines = file_size(modelFile,1);
    for(new line;line<maxlines;line++) {
        
        read_file(modelFile,line,szModel,charsmax(szModel),txtlen);
        if(equali(LastModel,szModel)) continue
        copy(LastModel,charsmax(LastModel),szModel);
        remove_filepath(szModel,szModelName,charsmax(szModelName));
        num_to_str(line,data,charsmax(data));
        menu_additem(menu,szModelName,data);
    }
    menu_display(id,menu)
    
    return PLUGIN_HANDLED;
}
public AddModelHandle(id,menu,item) {
    if(item == MENU_EXIT) {
        menu_destroy(menu)
        return PLUGIN_HANDLED;
    }
    new name[32],data[3], access, callback;
    menu_item_getinfo(menu,item,access,data,charsmax(data),name,charsmax(name),callback)
    new szModel[64],txtlen;
    read_file(modelFile,str_to_num(data),szModel,charsmax(szModel),txtlen);
    
    new Float:origin[3];
    fm_get_aim_origin(id,origin);
    
    new ent = engfunc(EngFunc_CreateNamedEntity,engfunc(EngFunc_AllocString,"info_target"));
    
    engfunc(EngFunc_SetOrigin,ent,origin);
    engfunc(EngFunc_SetModel,ent,szModel);
    entity_set_int(ent, EV_INT_solid, SOLID_BBOX );
    
    gCurEnt[id] = ent;
    
    menu_destroy(menu)
    SetModelOrigin(id);
    
    return PLUGIN_HANDLED
    
}
public SetModelOrigin(id) {
    
    new menu = menu_create("\yModelin Konumunu Ayarlayin","SetModelOriginHandler");
    
    menu_additem(menu,"Yukari","");
    menu_additem(menu,"Asagi","");
    menu_additem(menu,"X-ekseni +","");
    menu_additem(menu,"X-ekseni -","");
    menu_additem(menu,"Y-ekseni +","");
    menu_additem(menu,"Y-ekseni -","");
    menu_addblank(menu,0)
    menu_addblank(menu,0)
    new text[32];
    formatex(text,charsmax(text),"\rHassasiyet: \y%d",gSensitivity[id]);
    menu_additem(menu,text,"");
    menu_addblank(menu,0);
    menu_additem(menu,"\rKonum Ayarini Bitir");
    menu_setprop(menu,MPROP_PERPAGE,0);
    menu_setprop(menu,MPROP_EXIT,MEXIT_NEVER);
    menu_display(id,menu);
    return PLUGIN_HANDLED
}
public SetModelOriginHandler(id,menu,item) {
    new Float:origin[3];
    pev(gCurEnt[id],pev_origin,origin);
    new Float:changeval;
    switch(gSensitivity[id]) {
        case 1: changeval = 45.0;
            case 2: changeval = 15.0;
            case 3: changeval = 1.0;
        }
    
    switch(item) {
        case 7: {
            menu_destroy(menu);
            SetModelRotation(id);
            return PLUGIN_HANDLED;
        }
        case 0: {
            origin[2]+=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 1: {
            origin[2]-=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 2: {
            origin[0]+=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 3: {
            origin[0]-=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 4: {
            origin[1]+=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 5: {
            origin[1]-=changeval;
            engfunc(EngFunc_SetOrigin,gCurEnt[id],origin);
        }
        case 6: {
            gSensitivity[id]++;
            if(gSensitivity[id] >= 4) gSensitivity[id] = 1;
        }
    }
    menu_destroy(menu);
    SetModelOrigin(id);
    return PLUGIN_HANDLED;
}
public SetModelRotation(id) {
    new menu = menu_create("\yModelin Rotasyonunu Ayarlayin","SetModelRotationHandler");
    
    menu_additem(menu,"Pitch +","");
    menu_additem(menu,"Pitch -","");
    menu_additem(menu,"Yaw +","");
    menu_additem(menu,"Yaw -","");
    menu_additem(menu,"Roll +","");
    menu_additem(menu,"Roll -","");
    menu_addblank(menu,0)
    menu_addblank(menu,0)
    new text[32];
    formatex(text,charsmax(text),"\rHassasiyet: \y%d",gSensitivity[id]);
    menu_additem(menu,text,"");
    menu_addblank(menu,0)
    menu_additem(menu,"\rTekrar Konumu Ayarla");
    menu_additem(menu,"\rRotasyon Ayarini Bitir","");
    menu_setprop(menu,MPROP_PERPAGE,0);
    menu_display(id,menu);
    return PLUGIN_HANDLED
}
public SetModelRotationHandler(id,menu,item) {
    new Float:angle[3];
    pev(gCurEnt[id],pev_angles,angle);
    new Float:changeval;
    switch(gSensitivity[id]) {
        case 1: changeval = 45.0;
            case 2: changeval = 15.0;
            case 3: changeval = 1.0;
        }
    
    switch(item) {
        case 8: {
            menu_destroy(menu);
            gLastItem[id] = -1;
            SetModelAnimation(id);
            return PLUGIN_HANDLED;
        }
        case 0: {
            angle[0]+=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 1: {
            angle[0]-=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 2: {
            angle[1]+=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 3: {
            angle[1]-=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 4: {
            angle[2]+=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 5: {
            angle[2]-=changeval;
            set_pev(gCurEnt[id],pev_angles,angle);
        }
        case 7: {
            menu_destroy(menu)
            SetModelOrigin(id);
            return PLUGIN_HANDLED;
        }
        case 6: {
            gSensitivity[id]++;
            if(gSensitivity[id] >= 4) gSensitivity[id] = 1;
        }
    }
    
    menu_destroy(menu);
    SetModelRotation(id);
    return PLUGIN_HANDLED;
}
public SetModelAnimation(id) {
    new menu = menu_create("\yModelin Animasyonunu Secin (\rOnizlemek Icin Bir Kez \
    Secmek Icin Iki Kez Tiklayin.\y)","SetModelAnimationHandle");
    
    new model[64];
    pev(gCurEnt[id],pev_model,model,charsmax(model));
    
    new seqName[32];
    new i, data[4];
    
    while( getSequenceName(model,i++,seqName) ) {
        num_to_str(--i,data,charsmax(data));
        menu_additem(menu,seqName,data)
        ++i
    }
    
    menu_setprop(menu,MPROP_EXIT,MEXIT_NEVER);
    
    
    new page = gLastItem[id]/7;
    page = page < 0 ? 0:page
    menu_display(id,menu,page)
    return PLUGIN_HANDLED
}
public SetModelAnimationHandle(id,menu,item) {
    new seq = item;
    if(gLastItem[id] != seq) {
        gLastItem[id] = seq;
        
        set_pev(gCurEnt[id],pev_animtime,2.0);
        set_pev(gCurEnt[id],pev_framerate,1.0);
        set_pev(gCurEnt[id],pev_sequence,seq);
        
        menu_destroy(menu);
        SetModelAnimation(id);
        return PLUGIN_HANDLED
    }
    gLastItem[id] = -1;
    menu_destroy(menu);
    SetModelAnimationSub(id)
    return PLUGIN_HANDLED
}
public SetModelAnimationSub(id) {
    new menu = menu_create("\ySon Animasyon Ayari","SetModelAnimationSubHandle");
    
    menu_additem(menu,"Animasyonu Durdur","");
    menu_additem(menu,"Animasyon Secimine Geri Git","");
    menu_additem(menu,"Animasyon Secimini Bitir","");
    
    menu_setprop(menu,MPROP_EXIT,MEXIT_NEVER);
    menu_display(id,menu)
    return PLUGIN_HANDLED
}
public SetModelAnimationSubHandle(id,menu,item) {
    switch(item) {
        case 0: {
            set_pev(gCurEnt[id],pev_animtime,0.0);
            set_pev(gCurEnt[id],pev_framerate,0.0);
            menu_destroy(menu)
            SaveModel(id)
    
        }
        case 1: {
            menu_destroy(menu)
            SetModelAnimation(id)
        }
        case 2: {
            menu_destroy(menu)
            SaveModel(id)
        }
    }
    return PLUGIN_HANDLED
}
public SaveModel(id) {
    new menu = menu_create("\yModel Ayarlandi","SaveModelHandle");
    menu_additem(menu,"Modeli Kaydet","");
    menu_additem(menu,"Modeli Kaydetme (Sonraki Map Silinir)","");
    menu_addblank(menu,0)
    menu_additem(menu,"\rMODELI IPTAL ET","");
    menu_addblank(menu,0);
    menu_addblank(menu,0);
    menu_addblank(menu,0);
    menu_addblank(menu,0);
    menu_additem(menu,"\rAyarlara Geri Don");
    menu_setprop(menu,MPROP_PERPAGE,0);
    menu_display(id,menu)
    return PLUGIN_HANDLED;
}
public SaveModelHandle(id,menu,item) {
    switch(item) {
        case 0:{
            new szLine[256];
            
            new model[64], Float:origin[3], Float:angle[3], map[32],seq, Float:animtime;
            pev(gCurEnt[id],pev_model,model,charsmax(model))
            pev(gCurEnt[id],pev_origin,origin)
            pev(gCurEnt[id],pev_angles,angle)
            seq = pev(gCurEnt[id],pev_sequence);
            pev(gCurEnt[id],pev_animtime,animtime);
            get_mapname(map,charsmax(map));
            
            formatex(szLine,charsmax(szLine),"^"%s^" ^"%0.2f %0.2f %0.2f^" ^"%0.2f %0.2f %0.2f^" ^"%d^" ^"%d^" ^"%s^"",model,origin[0], origin[1],\
            origin[2],angle[0],angle[1],angle[2],seq,animtime?1:0,map);
            
            write_file(saveFile,szLine)
            
            client_print(id,print_chat,"[ Model Spawner ] Model kalici bellege kaydedildi: Haritaya entegre edildi.");
        }
        case 1:{
            client_print(id,print_chat,"[ Model Spawner ] Model gecici bellege kaydedildi: Harita degisiminde silinecek.");
        }
        case 2: {
            engfunc(EngFunc_RemoveEntity,gCurEnt[id]);
            client_print(id,print_chat,"[ Model Spawner ] Model silindi.");
        }
        case 3: {
            SetModelAnimationSub(id);
        }
    }
    
    menu_destroy(menu)
    return PLUGIN_HANDLED
}
/*
   *  CITATION:
   *  Stock: Finds the sequence name of passed model.
   *  Original Author: Arkshine
   
   *  Edited for an important issue by akcaliberkk
   *  - Removed caching
*/
stock getSequenceName( const model[], const sequence, sequenceName[], nameLen = sizeof sequenceName ) {
    static sequencesNameCached;
    static sequenceCount;
    static Array:arraySequencesName;
    
    if(sequencesNameCached ) {
        sequencesNameCached = 0;
        ArrayDestroy(arraySequencesName);
    }
    
    if( !sequencesNameCached ) {
        new f = fopen( model, "rb" );
        
        if( f ) {
            const studioHeader_NumSeq = 164;
            const mstudioseqdescSize  = 176;
            const sequenceNameLength  = 32;
            
            new sequenceIndex;
            
            fseek( f, studioHeader_NumSeq, SEEK_SET );{
                fread( f, sequenceCount, BLOCK_INT );
                fread( f, sequenceIndex, BLOCK_INT );
            }
            fseek( f, sequenceIndex, SEEK_SET );
            
            arraySequencesName = ArrayCreate( sequenceNameLength, sequenceCount );
            
            for( new i = 0; i < sequenceCount; i++ ) {
                fread_blocks( f, sequenceName, sequenceNameLength, BLOCK_CHAR );
                fseek( f, mstudioseqdescSize - sequenceNameLength, SEEK_CUR );
                
                ArrayPushString( arraySequencesName, sequenceName );
            }
            
            fclose( f );
            
            if( !( sequencesNameCached = !!ArraySize( arraySequencesName ) ) ) {
                ArrayDestroy( arraySequencesName );
                return 0;
            }
        }
    }
    
    if( sequencesNameCached && 0 <= sequence < sequenceCount ) {
        return formatex( sequenceName, nameLen, "%a", ArrayGetStringHandle( arraySequencesName, sequence ) );
    }

    return 0;
} 


---

---

Olmadı .d

---

---

Forum kurallarına bakmanızı öneririm, hemde moderatorsunuz kurallarda konuyu güncel tutmak yasaktır yazıyor.

---

---

plugin banada lazım coder arkadaşlar

---

---

Yarin bakicam bu konuya beklemede kalin

---

---

Deneyiniz...

---

---